Let’s Make a Game!

Step 13: Add Sound Effects

By Darrell Spice, Jr. (adapted by Duane Alan Hahn, a.k.a. Random Terrain)

As an Amazon Associate I earn from qualifying purchases.

Original Blog Entry

A quiet game is playable, but it's more fun with sound. The TIA produces 2 channel sound. The channels are known as channel 0 and channel 1. There are 3 registers for each channel to control the sound produced:

AUDC0, AUDC1 - Control of the channel, specifies the type of sound to generate. Values range from 0 to 15, though some values produce the same type of sound as others.
AUDF0, AUDF1 - Frequency of the channel, values range from 0 (highest) to 31 (lowest).
AUDV0, AUDV1 - Volume of the channel, values range from 0 (min) to 15 (max).

It's common to have a hand full of routines that handle sound effects. For Collect, these routines can be found in the new source code file sfx.asm. To add the file to collect.asm we use the include command:

       include sfx.asm

Besides the file, we also need to allocate 2 RAM variables to keep track of the sound effects:

; indexes for sound effect driver    
SFX_LEFT:       ds 1    ; stored in $B1
SFX_RIGHT:      ds 1    ; stored in $B2

The routines in sfx.asm are:

SFX_UPDATE - Must be called once every frame. This routine updates the 6 TIA registers listed above.
SFX_TRIGGER - must be called when there's a sound effect to generate, such as when an object is collected by the player. Use the Y register to denote which effect to trigger.
SFX_OFF - routine that silences the sound effects. If not required by your game, it can be commented out to save 15 bytes of ROM.

sfx.asm also includes a couple data tables that SFX_UPDATE uses to update the 6 TIA registers. Yes, only 2 tables even though there are 3 registers per channel to update. AUDCx and AUDVx both only require a nybbles worth of data, so their information is combined into a single byte to save ROM.

The tables are defined like this for Collect:

SFX_F:
    .byte 0, 31 ; collide
    .byte 0,  0,  0,  0,  1,  1,  1,  2,  2,  2,  3,  3,  3 ; collect
    .byte 0,  8,  8,  8,  8,  8,  8,  8,  8,  8,  8,  8,  8,  8,  8,  8 ; ping
    .byte 0, 31, 31, 31, 31, 31, 31, 31, 31, 31, 31, 31, 31, 31, 31, 31 ; game over

SFX_CV:
    .byte 0,$8f ; collide
sfxCOLLIDE = *-SFX_CV-1
    .byte 0,$6f,$6f,$6f,$6f,$6f,$6f,$6f,$6f,$6f,$6f,$6f,$6f ; collect
sfxCOLLECT = *-SFX_CV-1
    .byte 0,$41,$42,$43,$44,$45,$46,$47,$48,$49,$4a,$4b,$4c,$4d,$4e,$4f ; ping
sfxPING = *-SFX_CV-1
    .byte 0,$cf,$cf,$cf,$cf,$cf,$cf,$cf,$cf,$cf,$cf,$cf,$cf,$cf,$cf,$cf ; game over
sfxGAMEOVER = *-SFX_CV-1

Each .byte line contains the data for a single sound effect. The two tables are used together, so data in the first .byte line of SFX_F goes along with the data in the first .byte line in SFX_CV. The number of values must be the same in each table and each .byte line. The first value in each .byte line should be 0, it denotes end-of-sfx (though if you have a long-duration sound effect you could span it over multiple .byte lines).

Table SFX_CV looks a little complicated because of the extra lines such as sfxPING = *-SFX_CV-1. All those are doing is calculating the value to be used when you trigger a sound effect. You can name your sound effects whatever you want, just make sure it's followed by = *-SFX_CV-1 (also make sure you have a space before and after the equal sign).

Lets look at a single sound effect (that's been slightly changed from above for clarity) to explain how the data is used:

SFX_F:
    .byte 0,  1,  2,  3,  4,  5,  6,  7,  8,  9, 10, 11, 12 ; collect

SFX_CV:
    .byte 0,$64,$65,$66,$67,$68,$69,$6a,$6b,$6c,$6d,$6e,$6f ; collect
sfxCOLLECT = *-SFX_CV-1

To trigger the sound effect, you'll use this in your code:

ldy #sfxCOLLECT     ; select sound effect
        jsr SFX_TRIGGER     ; and trigger it

By triggering the sound effect, the value of sfxCOLLECT will be stored in one of the RAM variables. The value of sfxCOLLECT points to the 12 in the SFX_F table and the $6f in the SFX_CF table. When SFX_UPDATE is called (via jsr SFX_UPDATE), the 12 goes into AUDFx while the $6f will be split into two parts with the $6 going into AUDCx and the $f going into AUDFx. Lastly the pointer will be updated so it now points to 11 and $6e. After the next update they'll point to 10 and $6d, and so on until they point to 0 which means the end of the sound effect.

The order of the sound effects, as listed in the tables, is used to denote priority. The first sound effect has the lowest priority, so if both channels are busy and you try to trigger sound effect sfxCOLLIDE, nothing will happen. If both are busy and you try to trigger sfxGAMEOVER, the last sound effect, then one of the current sound effects will be aborted so sfxGAMEOVER can be heard.

SFX_UPDATE is called during Overscan:

OverScan:
        sta WSYNC       ; Wait for SYNC (halts CPU until end of scanline)
        lda #2          ; LoaD Accumulator with 2 so D1=1
        sta VBLANK      ; STore Accumulator to VBLANK, D1=1 turns image output off
        
    ; set the timer so the total number of scanlines ends up being 262
        lda #35
        sta TIM64T
        
        jsr SFX_UPDATE      ; update sound effects

While SFX_TRIGGER is called from a number of locations throughout the program. One of them is a tick sound that plays during the last 8 ticks of the timer:

DecrementTimer:
        lsr TimerPF+5   ; PF2 right side, reversed bits so shift right
        rol TimerPF+4   ; PF1 right side, normal bits so shift left
        ror TimerPF+3   ; PF0 right side, reversed bits so shift right
        lda TimerPF+3   ; only upper nybble used, so we need to put bit 3 into C
        lsr
        lsr
        lsr
        lsr
        ror TimerPF+2   ; PF2 left side, reversed bits so shift right
        rol TimerPF+1   ; PF1 left side, normal bits so shift left
        ror TimerPF     ; PF0 left side, reversed bits so shift right
        lda TimerPF+1   ; PF1 from left side
        and #%00011111  ; check the lower 5 bits
        bne NoTickSfx   ; branch if there's a value in the lower 5 bits
        ldy #sfxPING    ; else do a sound effect
        jsr SFX_TRIGGER
NoTickSfx:

In playing the game, I noticed it was harder to locate the box drawn by the ball, because it is the same color as the playfield, so I modified the program so it scores 2 points instead of just 1.

TestCollisions:
...
        bit CXP0FB          ; N=player0/playfield, V=player0/ball
        bvc notP0BL         ; if V is off, then player0 did not collide with ball
        ldy #0              ; which score to update
        ldx #4              ; which box was collected
        jsr Collect2ptBox   ; update score and reposition box
...
        bit CXP1FB          ; N=player1/playfield, V=player1/ball
        bvc notP1BL         ; if V is off, then player1 did not collide with ball
        ldy #1              ; which score to update
        ldx #4              ; which box was collected
        jsr Collect2ptBox   ; update score and reposition box

Collect2ptBox is a new routine that falls into CollectBox:

Collect2ptBox:
        lda #2              ; 2 point box
        .byte $2C           ; BIT with absolute addressing, trick that
                            ; causes the lda #1 to be skipped over
CollectBox:
        lda #1              ; 1 point per box
        sed                 ; SEt Decimal flag
        clc                 ; CLear Carry bit
        adc Score,y         ; add to player's current score

The ROM and the source are at the bottom of my blog entry.