Useful
Inventions
Favorite
Quotes
Game
Design
Atari
Memories
Personal
Pages

Let’s Make a Game!

Step 3: Score and Timer Display

By Darrell Spice, Jr. (adapted by Duane Alan Hahn)

Original Blog Entry

After getting a stable display, I like to implement the routines for displaying the score. You can see that in the first builds of Frantic, Medieval Mayhem, and Space Rocks. Even though we're not ready to show the player's score, the display is very useful for showing diagnostic informationsuch as this build of Frantic which uses it to show which sprites are colliding with the player.

 

To draw the score we're going to use the playfield graphics. The playfield pattern is comprised of 20 bits stored in 3 bytes of the TIA.

 

Andrew Davie posted this rather nice diagram in his 2600 Programming For Newbies tutorial which shows how that works:

Playfield Wierdness

The 20 bits are either repeated or reflected to draw the 20 bits on the right half of the screen.

 

For our game, a two digit score and a two digit timer will meet our requirements. We could show a single digit each in PF1 and PF2, but due to the reversed output of PF2 that would mean we'd need to create both normal and mirrored digit graphics. Instead, we're going to create digit graphics that are 3 bits across, which will allow us to show two digits using PF1. You may have seen the graphics in one of my blog entries with the revised mode file for jEdit. Each digit appears twice as we can use a simple mask to get the tens (AND #$F0) and ones (AND #$0F) digits. If we only saved the image as the ones position we'd need to apply 4 shift instructions to create a tens position image.

 

jEdit

 

PF1 is displayed twice on the screen and if we time it correctly we can change the contents of PF1 so that both sides of the screen are different. Andrew Davie posted another handy diagram that shows the timing:

 

Timing Diagram

 

In looking at the diagram we can figure out the update times required for each instance of PF1.

 

As mentioned before, the RIOT chip in the Atari 2600 stands for RAM, Input/Output and Timer. For this update we're going to look at the RAM and Input.

 

To show the score we need to keep track of a few things, so let's allocate some space in RAM:

        ORG $80             
 
    ; Holds 2 digit score, stored as BCD (Binary Coded Decimal)
Score:          ds 1    ; stored in $80
 
    ; Holds 2 digit timer, stored as BCD
Timer:          ds 1    ; stored in $81
 
    ; Offsets into digit graphic data
DigitOnes:      ds 2    ; stored in $82-$83, DigitOnes = Score, DigitOnes+1 = Timer
DigitTens:      ds 2    ; stored in $84-$85, DigitTens = Score, DigitTens+1 = Timer
 
    ; graphic data ready to put into PF1
ScoreGfx:       ds 1    ; stored in $86
TimerGfx:       ds 1    ; stored in $87
 
    ; scratch variable
Temp:           ds 1    ; stored in $88

Vertical Blank is now doing a little bit of work:

VerticalBlank:    
        jsr SetObjectColors
        jsr PrepScoreForDisplay
        rts             ; ReTurn from Subroutine

When the macro CLEAN_START initialized the Atari's hardware, it set all the colors to black. So we need to set the object colors if we want to see anything. This routine also reads the state of the console switches (via one of RIOT's Input registers) in order to determine if the player selected Color or Black & White:

SetObjectColors:        
        ldx #3          ; we're going to set 4 colors (0-3)
        ldy #3          ; default to the color entries in the table (0-3)
        lda SWCHB       ; read the state of the console switches
        and #%00001000  ; test state of D3, the TV Type switch
        bne SOCloop     ; if D3=1 then use color
        ldy #7          ; else use the b&w entries in the table (4-7)
SOCloop:        
        lda Colors,y    ; get the color or b&w value
        sta COLUP0,x    ; and set it
        dey             ; decrease Y
        dex             ; decrease X 
        bpl SOCloop     ; Branch PLus (positive)
        rts             ; ReTurn from Subroutine
        
Colors:   
        .byte $86   ; blue       - goes into COLUP0, color for player0 and missile0
        .byte $C6   ; green      - goes into COLUP1, color for player1 and missile1
        .byte $46   ; red        - goes into COLUPF, color for playfield and ball
        .byte $00   ; black      - goes into COLUBK, color for background
        .byte $0E   ; white      - goes into COLUP0, color for player0 and missile0
        .byte $06   ; dark grey  - goes into COLUP1, color for player1 and missile1
        .byte $0A   ; light grey - goes into COLUPF, color for playfield and ball
        .byte $00   ; black      - goes into COLUBK, color for background

The score and timer will be stored using BCD (Binary Coded Decimal) but for now we'll treat and display them as hexadecimal values (that's why the digit graphics are 0-9 then A-F). This routine takes the upper and lower nybble (4 bits) of the Score and Timer and multiplies them by 5 in order to get the offset into the digit graphic data. The 6507 does not have a multiply command, though it does have a shift feature which is equivalent to *2. If a nybble is value X then X * 2 * 2 + X is the same as X * 5:

PrepScoreForDisplay:
    ; for testing purposes, change the values in Timer and Score
        inc Timer       ; INCrement Timer by 1
        bne PSFDskip    ; Branch Not Equal to 0
        inc Score       ; INCrement Score by 1 if Timer just rolled to 0
        
PSFDskip        
        ldx #1          ; use X as the loop counter for PSFDloop
PSFDloop:
        lda Score,x     ; LoaD A with Timer(first pass) or Score(second pass)
        and #$0F        ; remove the tens digit
        sta Temp        ; Store A into Temp
        asl             ; Accumulator Shift Left (# * 2)
        asl             ; Accumulator Shift Left (# * 4)
        adc Temp        ; ADd with Carry value in Temp (# * 5)
        sta DigitOnes,x  ; STore A in DigitOnes+1(first pass) or DigitOnes(second pass)
        lda Score,x     ; LoaD A with Timer(first pass) or Score(second pass)
        and #$F0        ; remove the ones digit
        lsr             ; Logical Shift Right (# / 2)
        lsr             ; Logical Shift Right (# / 4)
        sta Temp        ; Store A into Temp
        lsr             ; Logical Shift Right (# / 8)
        lsr             ; Logical Shift Right (# / 16)
        adc Temp        ; ADd with Carry value in Temp ((# / 16) * 5)
        sta DigitTens,x ; STore A in DigitTens+1(first pass) or DigitTens(second pass)
        dex             ; DEcrement X by 1
        bpl PSFDloop    ; Branch PLus (positive) to PSFDloop
        rts             ; ReTurn from Subroutine

The Kernel's been modified so it now uses the data in DigitOnes and DigitTens to update PF1. Each line of graphic data is output twice so the digits are drawn over 10 scanlines which gives them a better appearance than if they had been drawn over 5 scanlines.

ldx #5

ScoreLoop:              ;   43 - cycle after bpl ScoreLoop
        ldy DigitTens   ; 3 46 - get the tens digit offset for the Score
        lda DigitGfx,y  ; 5 51 -   use it to load the digit graphics
        and #$F0        ; 2 53 -   remove the graphics for the ones digit
        sta ScoreGfx    ; 3 56 -   and save it
        ldy DigitOnes   ; 3 59 - get the ones digit offset for the Score
        lda DigitGfx,y  ; 5 64 -   use it to load the digit graphics
        and #$0F        ; 2 66 -   remove the graphics for the tens digit
        ora ScoreGfx    ; 3 69 -   merge with the tens digit graphics
        sta ScoreGfx    ; 3 72 -   and save it
        sta WSYNC       ; 3 75 - wait for end of scanline
;---------------------------------------        
        sta PF1         ; 3  3 - @66-28, update playfield for Score dislay
        ldy DigitTens+1 ; 3  6 - get the left digit offset for the Timer
        lda DigitGfx,y  ; 5 11 -   use it to load the digit graphics
        and #$F0        ; 2 13 -   remove the graphics for the ones digit
        sta TimerGfx    ; 3 16 -   and save it
        ldy DigitOnes+1 ; 3 19 - get the ones digit offset for the Timer
        lda DigitGfx,y  ; 5 24 -   use it to load the digit graphics
        and #$0F        ; 2 26 -   remove the graphics for the tens digit
        ora TimerGfx    ; 3 29 -   merge with the tens digit graphics
        sta TimerGfx    ; 3 32 -   and save it
        jsr Sleep12     ;12 44 - waste some cycles
        sta PF1         ; 3 47 - @39-54, update playfield for Timer display
        ldy ScoreGfx    ; 3 50 - preload for next scanline 
        sta WSYNC       ; 3 53 - wait for end of scanline
;---------------------------------------
        sty PF1         ; 3  3 - @66-28, update playfield for the Score display
        inc DigitTens   ; 5  8 - advance for the next line of graphic data
        inc DigitTens+1 ; 5 13 - advance for the next line of graphic data
        inc DigitOnes   ; 5 18 - advance for the next line of graphic data
        inc DigitOnes+1 ; 5 23 - advance for the next line of graphic data
        jsr Sleep12     ;12 35 - waste some cycles
        dex             ; 2 37 - decrease the loop counter
        sta PF1         ; 3 40 - @39-54, update playfield for the Timer display
        bne ScoreLoop   ; 2 42 - (3 43) if dex != 0 then branch to ScoreLoop
        sta WSYNC       ; 3 45 - wait for end of scanline
;---------------------------------------
        stx PF1         ; 3  3 - x = 0, so this blanks out playfield        
        sta WSYNC       ; 3  6 - wait for end of scanline

Score and Timer:

Score and Timer Color

When TV Type switched to B&W:

Score and Timer B&W

You'll notice that the score and timer are different colors even though they're both drawn using the playfield. This is because I've modified Vertical Sync to turn on SCORE mode. SCORE mode tells the TIA to use the color of player0 for the left half of the playfield and the color of player1 for the right half.

VerticalSync:
        lda #2      ; LoaD Accumulator with 2 so D1=1
        ldx #49     ; LoaD X with 49
        sta WSYNC   ; Wait for SYNC (halts CPU until end of scanline)
        sta VSYNC   ; Accumulator D1=1, turns on Vertical Sync signal
        stx TIM64T  ; set timer to go off in 41 scanlines (49 * 64) / 76
        sta CTRLPF  ; D1=1, playfield now in SCORE mode
...
        rts         ; ReTurn from Subroutine

The ROM and the source are at the bottom of my blog entry.

 

 

 

 

 

< Previous Step

 

 

Next Step >

 

 

 

 

 

Table of Contents for Let’s Make a Game!

Introduction

Goals for this tutorial.

Step 1: Generate a Stable Display

On other systems, the video chip generates the display; on the 2600, your program generates the display.

Step 2: Timers

Improve the display generation by using the built-in timer.

Step 3: Score and Timer Display

Using the playfield to display information.

Step 4: 2 Line Kernel

Draw the player objects (sprites) on screen (X & Y location).

Step 5: Automate Vertical Delay

Finish the Y positioning of the player objects (sprites).

Step 6: Spec Change

Revise our goals.

Step 7: Draw the Playfield

Display an arena (like the mazes in Combat).

Step 8: Select and Reset Support

Using the Game Select and Game Reset console switches.

Step 9: Game Variations

How to implement game variations (number of players, different mazes).

Step 10: “Random Numbers”

How to randomize your game.

Step 11: Add the Ball Object

Draw the ball on screen (X & Y location).

Step 12: Add the Missile Objects

Draw the missiles on screen (X & Y location)

Step 13: Add Sound Effects

Let’s make some noise!

Step 14: Add Animation

Make the humans run instead of glide.

 

 

 

 

Useful Links

Easy 6502 by Nick Morgan

How to get started writing 6502 assembly language. Includes a JavaScript 6502 assembler and simulator.

 

 

Atari Roots by Mark Andrews (Online Book)

This book was written in English, not computerese. It's written for Atari users, not for professional programmers (though they might find it useful).

 

 

Machine Language For Beginners by Richard Mansfield (Online Book)

This book only assumes a working knowledge of BASIC. It was designed to speak directly to the amateur programmer, the part-time computerist. It should help you make the transition from BASIC to machine language with relative ease.

 

 

The Second Book Of Machine Language by Richard Mansfield (Online Book)

This book shows how to put together a large machine language program. All of the fundamentals were covered in Machine Language for Beginners. What remains is to put the rules to use by constructing a working program, to take the theory into the field and show how machine language is done.

 

 

6502 Instruction Set with Examples

A useful page from Assembly Language Programming for the Atari Computers.

 

 

6502.org

Continually strives to remain the largest and most complete source for 6502-related information in the world.

 

 

Guide to 6502 Assembly Language Programming by Andrew Jacobs

Below are direct links to the most important pages.

 

 

Stella Programmer's Guide

HTMLified version.

 

 

Nick Bensema's Guide to Cycle Counting on the Atari 2600

Cycle counting is an important aspect of Atari 2600 programming. It makes possible the positioning of sprites, the drawing of six-digit scores, non-mirrored playfield graphics and many other cool TIA tricks that keep every game from looking like Combat.

 

 

How to Draw A Playfield by Nick Bensema

Atari 2600 programming is different from any other kind of programming in many ways. Just one of these ways is the flow of the program.

 

 

Cart Sizes and Bankswitching Methods by Kevin Horton

The "bankswitching bible." Also check out the Atari 2600 Fun Facts and Information Guide and this post about bankswitching by SeaGtGruff at AtariAge.

 

 

Atari 2600 Specifications

Atari 2600 programming specs (HTML version).

 

 

Atari 2600 Programming Page (AtariAge)

Links to useful information, tools, source code, and documentation.

 

 

MiniDig

Atari 2600 programming site based on Garon's "The Dig," which is now dead.

 

 

TIA Color Charts and Tools

Includes interactive color charts, an NTSC/PAL color conversion tool, and Atari 2600 color compatibility tools that can help you quickly find colors that go great together.

 

 

The Atari 2600 Music and Sound Page

Adapted information and charts related to Atari 2600 music and sound.

 

 

Game Standards and Procedures

A guide and a check list for finished carts.

 

 

Stella

A multi-platform Atari 2600 VCS emulator. It has a built-in debugger to help you with your works in progress or you can use it to study classic games.

 

 

JAVATARI

A very good emulator that can also be embedded on your own web site so people can play the games you make online. It's much better than JStella.

 

 

batari Basic Commands

If assembly language seems a little too hard, don't worry. You can always try to make Atari 2600 games the faster, easier way with batari Basic.

 

 

Back to Top

 

Disclaimer

View this page and any external web sites at your own risk. I am not responsible for any possible spiritual, emotional, physical, financial or any other damage to you, your friends, family, ancestors, or descendants in the past, present, or future, living or dead, in this dimension or any other.

 

Home Inventions Quotations Game Design Atari Memories Personal Pages About Site Map Contact Privacy Policy Tip Jar